# ".cshrc"                                                  by S.K. 
#	1996/08/02
#
# この.cshrc は会社のWS と共通で使用しているので、Linux と関係のない
# 設定も含まれています。
#

set path=(~/script ~/bin /usr2/local/bin /usr/local/bin /usr/local/bin/mh \
  /sbin /usr/sbin /usr/bin /bin /usr/bsd /usr/bin/X11 /etc /usr/etc \
  ~/sample/c /usr/local/game /usr2/local/game /usr/ucb /usr/demos/bin \
  /usr/openwin/bin /home4/publiss/BIN /usr/lib /u01/tuxedo/bin \
  /u02/tuxedo/bin .)
set cdpath = (~ ~/sample /usr ~/doc /usr3 /usr2)
set history = 100
set savehist = 10
set     filec
setenv  MORE        '-c'
setenv  JSERVER	localhost
#setenv MAILPATH	$MAIL
#setenv MANPATH "/usr/local/man /usr/catman /usr/man"

# コマンドプロンプトの設定
if ( $?prompt ) then
	if ( -o /bin/su ) then	# /bin/su のオーナー、すなわちroot の場合は
		set prompt="`hostname` (\!)# "        # プロンプトを'#' にする
	else
		set prompt="`hostname` (\!)% "        # root でない場合は '%'
	endif
endif


# ここから２０行ぐらい、仕事の設定
# Linux には関係ない
if( `hostname` == hpf10 ) then
	setenv ROOTDIR          /u02/tuxedo
	setenv APPDIR           /users/user1/`hostname`_service5
else if( `hostname` == hpe55 ) then
	setenv ROOTDIR          /u01/tuxedo
	setenv APPDIR           /users/user1/`hostname`_service5
else
	setenv ROOTDIR          /u01/tuxedo
	setenv APPDIR           /tmp_mnt/home/sparc20/user1/`hostname`_service5
endif
setenv ORACLE_HOME      /u01/oracle
setenv ORACLE_SID       oraeuc
setenv ORACLE_TERM      xsun5
setenv ORA_NLS 			$ORACLE_HOME/ocommon/nls/admin/data
setenv NLS_LANG         japanese_japan.ja16euc
setenv ORAKITPATH       /u01/oracle/forms30/admin/resource
setenv MENU5PATH 		$ORACLE_HOME/forms30/admin/resource
setenv SHLIB_PATH       $ROOTDIR/lib
setenv TUXCONFIG        $APPDIR/tuxconfig
setenv VIEWFILES		service4_view.V
setenv VIEWDIR			$APPDIR

if(`uname -s` != Linux) then
	setenv  TZ			JST-9
	setenv FAXSERVER beguine
endif


# 次からはIRIS 用の設定
if(`uname -s` == IRIX ) then
	setenv MODEM    /dev/ttyf2
	setenv LANG ja_JP.EUC
#	setenv LANG C
	setenv XMODIFIERS @im=_XWNMO
else if(`uname -s` == NonStop-UX) then  # for TANDEM machine
	setenv LANG C
	setenv KCODE    EUC
else if(`uname -s` == HP-UX) then
	setenv LANG japanese.euc

#==========================================================================
# 次からはLinux 用の設定
#==========================================================================
else if(`uname -s` == Linux) then
	setenv LANG ja_JP.EUC
	setenv XMODIFIERS @im=kinput2
	setenv KCODE	EUC
	setenv MODEM    /dev/modem
	setenv XC_PATH  $HOME/xc			# xc という通信ソフト用
	setenv PAGER	less
	stty dec		# under xdm, ".login" is not refrected!
else
	setenv LANG		japanese
	setenv KCODE	EUC
endif


alias   a           alias
a       .           source
if( `hostname` == lhuga) then
	a		nemacs		'~/script/mu \!*'
endif
a       h           history
a       p           pwd
a       rm          rm -i
a       cls         clear
a       cl          clear
a       ff          whereis
a		pd			pushd
a		inf			'sccs info'
a		g			"grep -i -n \!* *.[ch]"
a		gp			'gp -s $HOME/.gprc \!*'
a		nes			'mule -nw -e shell'
a		tt			'ls -l \!*; tracker \!*'
a		ls			'ls -aCF'


if(`uname -s` == IRIX) then
	a		tandem		'rlogin tandem;  clear'
	a		ne			'nemacs \!*; clear'
	a		xv			'xv -visual truecolor'
	a		expand		tabfl
	a		js			jshowcase
	a		jsr			'jshowcase -s'
	a		bupenv		bupenv_lhuga
else
	a		xlock	'xlock -mode flame'
	a		ne		'mule -nw \!*'
	a		tabfl	'expand \!*'
endif

a		rmail	'ne -e rmail'


if ( $?prompt ) then
if ($?TERM) then

	#=========================================================================
	# kterm のタグにカレントディレクトリを表示する設定
	# "^[" はエスケープシーケンスで、２文字ではなく１文字！
	# (vi の場合はCtrl-v の後、Esc キー, Mule の場合はCtrl-q の後にEsc で入力)
	#=========================================================================
	if ($TERM == xterm || $TERM == kterm || $TERM == iris-ansi) then
		if( -x /usr/bsd/rlogin ) then
			set rlogin_cmd=/usr/bsd/rlogin
		else if( -x /usr/bin/rlogin ) then
			set rlogin_cmd=/usr/bin/rlogin
		else
			set rlogin_cmd=telnet
		endif
		alias xpwd 'echo -n "]2;"`hostname`\(`whoami`\)`/bin/pwd`""'
		alias cd 'set old=$cwd; chdir \!*;xpwd'
		alias pwd '/bin/pwd \!*;xpwd'
		alias rlogin 'echo -n "]2;Rlogin "\!*"";$rlogin_cmd \!* ;xpwd'
		alias su 'echo -n "]2;Su "\!*"";/bin/su \!* ;xpwd'
   	     xpwd
	else
		alias cd 'set old=$cwd; chdir \!*;/bin/pwd'
	endif
	if(`uname -s` == NonStop-UX) then   # for TANDEM machine
		if( $TERM == kterm ) then
			setenv TERM xterm
		endif
		alias db_sjis 'setenv NLS_LANG JAPANESE_JAPAN.SJIS'
	endif

	#=========================================================================
	# Special CD
	# よく行くディレクトリへ一発で移動できるように、様々なエリアスを切ってます
	#=========================================================================
	alias back 'set back=$old; set old=$cwd; cd $back; unset back; dirs'
	alias cdinc 'cd /usr/include'
	alias cdsys 'cd /usr/include/sys'
	if ( -d /var/sysgen ) then			# for IRIX over 5.x
		alias cdgen 'cd /var/sysgen'
		alias cdmasd 'cd /var/sysgen/master.d'
	else
		alias cdgen 'cd /usr/sysgen'
		alias cdmasd 'cd /usr/sysgen/master.d'
	endif
	alias cdf	'cd /usr2/local/freesoft'
	alias cdj	'cd ~/../4Dgifts/japanese_sys/pub'
	alias cdcli	'cd ~/work/raccoon/menu/cli/src'
	alias cdsv	'cd ~/work/raccoon/menu/sv/src'

	if( -d /home1 ) then
		alias cds	'cd /home1/SEIGYO'
	else
		alias cds	'cd /usr2/oltp/SEIGYO'
	endif

	#Terminal alias
	if(`uname -s` == IRIX) then
	alias kterm	'kterm -ms red -cr white -km euc -sb -fn 8x16 -fk k16 +sf'
	else
	alias kterm	'kterm -km euc -sl 1024 -sb -bg gray90 -fg black -fn 7x14 -fk k14 +sf'
	endif
endif
endif