//-------------------------------------　デフォルト設定
    exportInfo.destination = new String("");
    exportInfo.fileNamePrefix = new String("untitled_");
    exportInfo.visibleOnly = false;
    exportInfo.fileType = 1; // JPEG=1, PSD=2, TIFF=3, PDF=4, Targa=5, BMP=6
    exportInfo.icc = false;
    exportInfo.jpegQuality = 5;
    exportInfo.psdMaxComp = false;
    exportInfo.tiffCompression = TIFFEncoding.NONE;
    exportInfo.tiffJpegQuality = 8;
    exportInfo.pdfEncoding = PDFEncoding.JPEG;
    exportInfo.pdfJpegQuality = 8;
    exportInfo.targaDepth = TargaBitsPerPixels.TWENTYFOUR;
    exportInfo.bmpDepth = BMPDepthType.TWENTYFOUR;
//-------------------------------------------------

// --------*作業対象ファイルのあるフォルダの直下にcutフォルダを作っておく------------
      var saveFile = new File(exportInfo.destination + "/cut/" + fileNameBody + ".jpg");
//--------------------------------------------------------------------  

//--------　レイヤーネーム　省略 --------
//        fileNameBody += "_" + layerName;
//---------------------------------- 

//--------　開始ダイアログ　表示省略-------------
//    if (0 == settingDialog(exportInfo)) return; // quit
// -----------------------------------------

//--------------------　終了ダイアログ 表示省略------
//          alert(uiTitleLayersToFiles + uiAlertWasSuccessful);
//------------------------------------------------

// SliceLayer
// westvill
// アニメレイヤーを1フレーム毎にレイヤーに展開 。ターゲットレイヤーのスタート位置に合わせて下方向にレイヤーを追加します。
//レイヤー名を連番化。 最大フレーム数は999
// また、1フレームのアニメレイヤーに適用すると静止画レイヤーに変換します。
//トップレイヤーがアニメーションレイヤーになっていたのを修正(2006/03/22)
Param none
tv_LayerCurrentID
    TopID = result
tv_LayerInfo TopID                            //レイヤー情報取得
parse result display position opacity name type startframe endframe prelighttable 
                                                //返り値を変数にセット
CheckAnim = CMP(type,"IMAGE")
    if (CheckAnim == 1)                                 // アニメレイヤーでない時は終了
        tv_Warn "Layer Must Be An Anim Layer!"
        exit
    end
////　メインループ
do
    tv_LayerImage EndFrame
    tv_LayerCut
      num = EndFrame - startframe + 1
if (num > 999)                            //フレーム数が999より大きい時は終了
    exit
end 
length = LEN(num)         // 数字の桁に合わせてゼロを追加
if (length == 1)
    znum = concat ("_00",num)
end
if (length == 2)
    znum = concat ("_0",num)
end
if (length == 3)
    znum = concat ("_",num)
end
    Lname = concat (name,znum)
    tv_LayerCreate Lname
    currentlayer = result
    tv_LayerPaste
    tv_LayerShift  currentlayer startframe  //ターゲットレイヤーのスタート位置に合わせる
    tv_LayerSet TopID
    EndFrame = EndFrame - 1
until ((EndFrame -startframe + 1) == 0)
////　ループを抜けた時点で最上位二つのレイヤーが入れ替わっている。
tv_LayerCurrentID
    IDs = result  
tv_LayerGetPos IDs    
    Pos = result
    Pos = Pos - 1 
tv_LayerMove Pos     //スタートフレームレイヤーを一つ上に移動
tv_Display current               //カレント表示モードにする
exit

// Input-framelayer
// westvill
//
//基本的にSlicelayer.grg適用後等のレイヤー群にフレーム長を入力するものです。
//数値を入力すると下のレイヤーに移動して順次入力していく事が出来ます。（元のフレーム数は1でなくても可）
//"Cancel"クリック、最下位レイヤーで終了。
//"0"を入力するとスキップします。
//スタートはどこからでも可。また、レイヤー位置を揃えてなくても大丈夫です。
Param none
    tv_Request "Key? |Frame|Time"  //入力値が"フレーム"か"時間"かを選択 
        data =result                        // Frameの時は"1" Timeの時は"0"
    tv_ProjectCurrentID
        projectID = result
    tv_Projectinfo   projectID
        parse result name width height aspect framerate filedmode startframe //プロジェクトのフレームレートのみ使用
                                                                                             //*プレビュー再生のレートではありません 
do
    if (CMP(data,"0") == 1)
        tv_ReqFloat 1 0 99 "Input Times"    //初期値1、最小値0（スキップ)、最大値99）　(単位は秒) 　(1+12k、24fps)→1.5
            times = result
        if (CMP(times,"cancel") == 1)
            exit
        end 
        count = times*framerate   //秒数×フレームレート
    else
        tv_ReqNum 1 0 999 "Input Frames"    //初期値1、最小値0(スキップ)、最大値999）　(単位はフレーム) 　
            times = result
        if (CMP(times,"cancel") == 1)
            exit
        end 
        count = times
    end
    tv_LayerCurrentID
        ID = result                                 //カレントレイヤーIDを取得
    tv_LayerInfo ID                //レイヤー情報取得
        parse result display position opacity name type start end1 prelighttable posth selection
    length= (end1 - start + 1)        //*現在のレイヤーフレーム数取得 
        if (times == 0)                            //"0"が入力されたら差分=0に
            count = 0
        else
            count = count - length         //入力されたフレーム数と現在のフレーム数の差分
        end
    tv_LayerStretch ID "end" count "fast"       //カレントレイヤーをストレッチ 
                                                          //start位置を保持してend方向にストレッチ。補間無し
    tv_LayerGetPos ID                           //カレントレイヤーの位置(上下方向)を取得
        Pos = result
    tv_LayerGetID (Pos+1)                     //一つ下のレイヤーIDを取得
        ID = result
    tv_LayerSet ID                                //カレントレイヤーを移動
until (CMP(ID,"NONE") == 1)                     // 次のレイヤーが無い場合、終了
exit

// Writelayers.grg
// westvill
//
//　各レイヤ-のフレーム数をconfig.ini中の[カット名]セクションに書き出します。　c00n=m(フレーム数または時間)
//レイヤーの並びは任意で可。（揃えておく必要はありません）
//Mirage起動中にconfig.iniをエディターなどで編集した場合はその変更は反映されません。
//Writelayers.grgで書き出した内容はMirage終了時にiniファイルに反映されます。
//Writelayers.grgで書き出した内容はMirage起動中にReadlaｙer.grgで読み込み出来ます。
//不要なセクションは適時消去して下さい。config.iniが巨大になると起動、終了が遅くなります。
Param none
    tv_Request "Key? |Frame|Time"  //出力値が"フレーム"か"時間"かを選択 
                                              //*割り切れないフレームレート（30、24、12等）では"フレーム"を選択して下さい。 
        data =result                        // Frameの時は"1" Timeの時は"0"
    tv_ProjectCurrentID
        projectID = result
    tv_Projectinfo   projectID
        parse result name width height aspect framerate filedmode startframe //プロジェクトのフレームレートのみ使用
                                                                                                       //*プレビュー再生のレートではありません
    i = 0
DO                             //レイヤーID取得ルーチン
     tv_LayerGetID i
     i = i + 1
      ID(i) = result
UNTIL (cmp(ID(i),"NONE") == 1)
        Lnum= i - 1      //レイヤー総数
    if (Lnum > 999)       //レイヤー数が999を超える場合は終了
        exit
        tv_warn "レイヤー数が999を超えています"
    end
    tv_ReqString "Title ?"      //カット名（作品名）入力待ち
        title = result
    if (cmp(title,"cancel") == 1)
        exit
    end
for Li= 1 to Lnum
    tv_LayerInfo ID(Li)             //レイヤー情報取得
        parse result display position opacity name type start end prelighttable posth selection
    atime(Li)= (end - start + 1)
    length1 = LEN(Li)
                               // 桁数に応じてゼロを追加
    if (length1 == 1)
        znum = concat ("c00",Li)
    end
    if (length1 == 2)
        znum = concat ("c0",Li)
    end
    if (length1 == 3)
        znum = concat ("c",Li)
    end
    if (data == 0)
        atime(Li) = atime(Li)/framerate    //出力値が時間の時はフレームレート(プロジェクトに依存)で除算
        tv_WriteUserString title "data" "time"
    else
        tv_WriteUserString title "data" "frame      "
    end
    tv_WriteUserString title znum atime(Li)
end
    print title"　を　"Lnum"レイヤー　書き出しました"
    tv_ReadUserString "Writehistory" "hist"  " "   //iniファイルから書き込みセクション名の履歴を読み取り
        parse result hist1 hist2 hist3 hist4 hist5
    hist1 =" """hist1       //文字列の頭に" "(スペース)を挿入   
    hist2 =" """hist2
    hist3 =" """hist3
    hist4 =" """hist4
    historynew =title""hist1""hist2""hist3""hist4
    tv_WriteUserString "Writehistory" "hist" historynew            //config.iniに履歴を書き込み
exit

// Readlayesr.grg
// westvill
//Read frames from [title] section in config.ini
//各レイヤ-のフレーム数をconfig.ini中の[カット名]セクション以下の　　c00n(n=1〜)=m(フレーム数または時間)　から読み出して適用する。
//レイヤーの並びは任意で可。（揃えておく必要はありません）
//各レイヤーのスタート位置は保持されます。
//Mirage起動中にconfig.iniをエディターなどで編集した場合はその変更は反映されません。
//Writelayers.grgで書き出した内容はMirage終了時にiniファイルに反映されます。
//Writelayers.grgで書き出した内容はMirage起動中にReadlaｙer.grgで読み込み出来ます。
Param none
    tv_ProjectCurrentID
        projectID = result
    tv_Projectinfo   projectID
        parse result name width height aspect framerate filedmode startframe //プロジェクトのフレームレートのみ使用
                                                                                                        //*プレビュー再生のレートではありません
    i = 0
DO                              // レイヤーID取得ルーチン
     tv_LayerGetID i
     i = i + 1
      ID(i) = result
UNTIL (cmp(ID(i),"NONE") == 1)
        Lnum= i - 1      //レイヤー総数
    tv_ReadUserString "Writehistory" "hist"  "0"   //iniファイルから書き込み履歴読み取り
    parse result t1 t2 t3 t4 t5
    if (CMP(t1,"0") == 1)       // 行が存在しない時終了
        tv_warn "履歴がありません"
    else
        print t1 t2 t3 t4 t5         //履歴を表示　　*ここで選択できると便利なんですが…
    end 
    tv_ReqString "Title ?"       //カット名（読み込むセクション名） 入力待ち
    title = result
    if (cmp(title,"cancel") == 1)
        exit
    end
    tv_ReadUserString title "data" "0"   //iniファイルから入力値の形式読み取り (frameかtime)
        data = result
    if (CMP(data,"0") == 1)
        tv_warn "データがありません"
        exit
    end
for Li = 1 to Lnum
    length1 = LEN(Li)        
                                        //行の名前生成
    if (length1 == 1)
        znum = concat ("c00",Li)
    end
    if (length1 == 2)
        znum = concat ("c0",Li)
    end
    if (length1 == 3)
        znum = concat ("c",Li)
    end
    tv_ReadUserString title znum "0"   //iniファイルから読み取り
    times = result
    if (CMP(times,"0") == 1)       // 行が存在しない時終了
        exit
    end 
    if (CMP(data, "time") == 1)
        times = times*framerate    //入力値が時間の時はフレームレート(プロジェクトに依存)を乗算
    end 
    tv_LayerInfo ID(Li)                //レイヤー情報取得
    parse result display position opacity name type start end1 prelighttable posth selection
    length= (end1 - start + 1)        //現在のレイヤーフレーム数取得
          num = times - length         //iniファイルに記述されているフレーム数との差分
        tv_LayerStretch ID(Li) end num fast    //レイヤーをストレッチ 
                                                          //start位置を保持してend方向にストレッチ。補間無し
end
//ここにslidelayers.grgをコピー&ペーストしておくと自動で並び替えてくれるので便利です。
exit